grads画径向平均风场和水汽通量散度出错了

juliekxkl

我想画100-125E 850hPa平均风场和水汽通量散度，即以时间和纬度为坐标，

画出来的图却是单线图，纠结了很久，实在没办法了，求大神帮忙啊！脚本如下
'reinit'
'open E:\grads\data\fnl_20100506_06_00.ctl'
'set map 15 1 9'
'set parea 1 10.2 1.5 8'
'set xlopts 1 6 0.14'
'set ylopts 1 6 0.14'
'set mpdset cnworld'
'set font 0'
'set display color white'

*-------计算----------
*'set lev 1000 100'
'set lev 850'
'define prs=lev'
'define g=9.8'
'define es=6.112*exp(17.67*(TMPprs-273.16)/(TMPprs-29.65))'
*饱和比湿的计算  单位：克/克
'define qs=0.62197*es/(prs-0.378*es)'
'define q=qs*RHprs/100'
'set lev 1000 300'
'define qdiv=hdivg(q*UGRDprs*1000/g,q*VGRDprs*1000/g)*100000'
'set grads off'
'set grid off'
'set t 1 6'
'set lat 16 29'
*'set lon 100 125'
'set csmooth on'
'define qdiva=ave(qdiv,lon=100,lon=125，t=1,t=6)'
'define u1=ave(ugrdprs,lon=100,lon=125)'
'define v1=ave(vgrdprs,lon=100,lon=125)'
'set lat 16 29'
'set lev 850'
'set gxout shaded'
'd qdiva'
'cbarn'
'd u1'
*'set gxout vector'
*'d u1;v1'
'draw string 0.9 0.15 10e-5 s-1'
'printim E:\grads\data\tu\wind_div.png'

river

亲，有一点要注意啊。求的是纬向平均么，那就不需要对时间求平均啦，都求完了不就剩下一个值了么。还有就是求了纬向平均之后那就相当于纬度是固定的了，所以要加上一句'set lon 1'。那个1可以是任意一个数哦，图是没有变化的，亲可以试试哦。

亲已经离成功很近了，就差那么一点点了。应该是这样的就对了：
'reinit'
'open E:\grads\data\fnl_20100506_06_00.ctl'
*'set map 15 1 9'
'set parea 1 10.2 1.5 8'
'set xlopts 1 6 0.14'
'set ylopts 1 6 0.14'
*'set mpdset cnworld'
'set font 0'
*'set display color white'

*-------计算----------
*'set lev 1000 100'
'set t 1 6'
'set lev 850'
'define prs=lev'
'define g=9.8'
'define es=6.112*exp(17.67*(TMPprs-273.16)/(TMPprs-29.65))'
*饱和比湿的计算  单位：克/克
'define qs=0.62197*es/(prs-0.378*es)'
'define q=qs*RHprs/100'
'set lev 1000 300'
'define qdiv=hdivg(q*UGRDprs*1000/g,q*VGRDprs*1000/g)*100000'

'set lon 1'
'define qdiva=ave(qdiv,lon=100,lon=125)'
'define u1=ave(ugrdprs,lon=100,lon=125)'
'define v1=ave(vgrdprs,lon=100,lon=125)'

'set grads off'
'set grid off'
'set lat 16 29'
*'set lon 100 125'
'set csmooth on'
'set gxout shaded'
'd qdiva'
'cbarn'
'd u1'
*'set gxout vector'
*'d u1;v1'
'draw string 0.9 0.15 10e-5 s-1'
'printim E:\grads\data\tu\wind_div.png'
;
还有啊亲，一定要注意时间要放在最前面设置。哦，还有一点，你画的是时间--纬度图，类似于剖面图啊，不需要设置地图啊，虽然设置了不应影响画图，但是gs就会显得比较乱。如果你想让时间显示成X轴还可以加上'set xyrev on'。
就这么多，完毕

river

'define qdiva=ave(qdiv,lon=100,lon=125，t=1,t=6)'这一句求的是什么平均？

风雨雷电

river 发表于 2012-12-22 11:16

                               
登录/注册后可看大图

'define qdiva=ave(qdiv,lon=100,lon=125，t=1,t=6)'这一句求的是什么平均？

我也认为这个地方的平均不明确。是否前面加上一句：
'set lev 850'  ?
而且其中  t=1,  t=6  与时间定义' set  t  1  6' 有冲突

river

风雨雷电 发表于 2012-12-22 11:22

                               
登录/注册后可看大图

我也认为这个地方的平均不明确。是否前面加上一句：
'set lev 850'  ?
而且其中  t=1,  t=6  与时间定 ...

他说他求的是纬向平均，还对时间求平均明显和他想要的是冲突的啊，而且里面的一个逗号还是中文状态下的。我觉得能出来图已经很让人惊讶了

风雨雷电

river 发表于 2012-12-22 11:35

                               
登录/注册后可看大图

他说他求的是纬向平均，还对时间求平均明显和他想要的是冲突的啊，而且里面的一个逗号还是中文状态下的。 ...

是的，中文逗号。观察的真仔细！

juliekxkl

river 发表于 2012-12-22 19:32

                               
登录/注册后可看大图

亲，有一点要注意啊。求的是纬向平均么，那就不需要对时间求平均啦，都求完了不就剩下一个值了么。还有就是 ...

亲 ，不愧是大神啊，解决了，太谢谢你的悉心指导了，自己倒腾了很久也没发现问题，还是得在家园里找出路啊

juliekxkl

风雨雷电 发表于 2012-12-22 11:22

                               
登录/注册后可看大图

我也认为这个地方的平均不明确。是否前面加上一句：
'set lev 850'  ?
而且其中  t=1,  t=6  与时间定 ...

嘿嘿  不好意思哈！纯属笔误，就是'define qdiva=ave(qdiv,lon=100,lon=125)',现在问题解决了

流浪的心

给力，点赞！