新手向各位求助！！！

Jaquelinluo

本人刚开始接触NCL，属于初级菜鸟级别。目前自己编了一个程序，是将.txt格式的文件转化为.nc格式的。程序如下：

begin

f = addfile("coemission.nc","c")
;creat the file

nlat = 141
nlon = 121
dim_names = (/"lat","lon"/)
dim_sizes = (/nlat,nlon/)
dim_unlimited = (/False,False/)
filedimdef(f,dim_names,dim_sizes,dim_unlimited)
;define dimensions

atts = True
atts@title = "Sample"
atts@conventions = "None"
atts@creation_date = systemfunc("date")
fileattdef(f,atts)
;creat global attributes



filevardef(f,"lat","float","lat")
filevardef(f,"lon","float","lon")
filevardef(f,"emi_co","float",(/"lat","lon"/))
;define file variables


latatts = True
latatts@long_name = "latitude"
latatts@units = "degrees_north"
filevarattdef(f,"lat",latatts)

lonatts = True
lonatts@long_name = "longitude"
lonatts@units = "degrees_east"
filevarattdef(f,"lon",lonatts)

emi_coatts = 0.0
emi_coatts@long_name ="emission of co"
emi_coatts@units = "None"
emi_coatts@_FillValue = 1
filevarattdef(f,"emi_co",emi_coatts)
;define each variable's attributes


lat = fspan(-90,90,nlat)
f->lat = (/lat/)
lon = fspan(-180,180,nlon)
f->lon = (/lon/)
;creat coordinate arrays

;generate a 2D array

z = asciiread("out.2008_D1.txt",(/141,121/),"float")

f->$"emi_co"$ = z

end
但是每次执行的时候都会提示出错
fatal:Could not create (coemission.nc)
fatal:["Execute.c":8128]:Execute: Error occurred at or near line 11 in file txt2nc.ncl
也就是在filedimdef(f,dim_names,dim_sizes,dim_unlimited)附近出错。
我找了很多遍，都没找到错误所在，所以前来向各位求助

Jaquelinluo

已经解决了，谢谢大家！

2.7

把
systemfunc("rm coemission.nc")
放在你的addfile之前 就好了

Jaquelinluo

2.7 发表于 2013-12-11 10:51

                               
登录/注册后可看大图

把
systemfunc("rm coemission.nc")
放在你的addfile之前 就好了

嗯，谢谢

wkl

碰到一样的问题，求问怎么解决的啊

yelulu

初学正在txt转nc，总是在报错，对于单站不同时刻的数据应该怎么赋值呢