如何处理WEFout1000hpa的飞，压，温，湿

guarenyouji

1. ;   Example script to produce plots for a WRF real-data run,
   
2. ;   with the ARW coordinate dynamics option.
   
3. ;   Interpolating to specified pressure levels
   
4. 
   
5. load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
   
6. load "$NCARG_ROOT/lib/ncarg/nclscripts/wrf/WRFUserARW.ncl"
   
7. ;load "./WRFUserARW.ncl"
   
8. 
   
9. begin
   
10. ;
    
11. ; The WRF ARW input file.  
    
12. ; This needs to have a ".nc" appended, so just do it.
    
13.   a = addfile("../wrfout_d01_2000-01-24_12:00:00.nc","r")
    
14. 
    
15. 
    
16. ; We generate plots, but what kind do we prefer?
    
17.   type = "x11"
    
18. ; type = "pdf"
    
19. ; type = "ps"
    
20. ; type = "ncgm"
    
21.   wks = gsn_open_wks(type,"plt_PressureLevel2")
    
22. 
    
23. 
    
24. ; Set some basic resources
    
25.   res = True
    
26.   res@MainTitle = "REAL-TIME WRF"
    
27.   res@Footer = False
    
28. 
    
29.   pltres = True
    
30.   mpres = True
    
31.   mpres@mpGeophysicalLineColor      = "Black"
    
32.   mpres@mpNationalLineColor         = "Black"
    
33.   mpres@mpUSStateLineColor          = "Black"
    
34.   mpres@mpGridLineColor             = "Black"
    
35.   mpres@mpLimbLineColor             = "Black"
    
36.   mpres@mpPerimLineColor            = "Black"
    
37.   mpres@mpGeophysicalLineThicknessF = 2.0
    
38.   mpres@mpGridLineThicknessF        = 2.0
    
39.   mpres@mpLimbLineThicknessF        = 2.0
    
40.   mpres@mpNationalLineThicknessF    = 2.0
    
41.   mpres@mpUSStateLineThicknessF     = 2.0
    
42. 
    
43. 
    
44. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    
45. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    
46. 
    
47. ; What times and how many time steps are in the data set?
    
48.   times = wrf_user_getvar(a,"times",-1)  ; get all times in the file
    
49.   ntimes = dimsizes(times)         ; number of times in the file
    
50. 
    
51. ; The specific pressure levels that we want the data interpolated to.
    
52.   pressure_levels = (/ 1000., 850., 700., 500., 300., 100./)   ; pressure levels to plot
    
53.   nlevels         = dimsizes(pressure_levels)           ; number of pressure levels
    
54. 
    
55. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    
56. 
    
57.   do it = 0,ntimes-1               ; TIME LOOP
    
58. 
    
59.     print("Working on time: " + times(it) )
    
60.     res@TimeLabel = times(it)   ; Set Valid time to use on plots
    
61. 
    
62. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    
63. ; First get the variables we will need        
    
64. 
    
65.     tc = wrf_user_getvar(a,"tc",it)        ; T in C
    
66.     u  = wrf_user_getvar(a,"ua",it)        ; u averaged to mass points
    
67.     v  = wrf_user_getvar(a,"va",it)        ; v averaged to mass points
    
68.     p  = wrf_user_getvar(a, "pressure",it) ; pressure is our vertical coordinate
    
69.     z  = wrf_user_getvar(a, "z",it)        ; grid point height
    
70.     rh = wrf_user_getvar(a,"rh",it)        ; relative humidity
    
71. 
    
72. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    
73. 
    
74.     do level = 0,nlevels-1                 ; LOOP OVER LEVELS
    
75. 
    
76.       pressure = pressure_levels(level)
    
77. 
    
78.       tc_plane = wrf_user_intrp3d(tc,p,"h",pressure,0.,False)
    
79.       z_plane  = wrf_user_intrp3d( z,p,"h",pressure,0.,False)
    
80.       rh_plane = wrf_user_intrp3d(rh,p,"h",pressure,0.,False)
    
81.       u_plane  = wrf_user_intrp3d( u,p,"h",pressure,0.,False)
    
82.       v_plane  = wrf_user_intrp3d( v,p,"h",pressure,0.,False)
    
83. 
    
84.       u_plane = u_plane*1.94386     ; kts
    
85.       v_plane = v_plane*1.94386     ; kts
    
86.       u_plane@units = "kts"
    
87.       v_plane@units = "kts"
    
88. 
    
89. 
    
90.       ; Plotting options for T               
    
91.         opts = res                          
    
92.         opts@cnLineColor = "Red"
    
93.         opts@ContourParameters = (/ 5.0 /)
    
94.         opts@cnInfoLabelOrthogonalPosF = 0.07  ; offset second label information
    
95.         opts@gsnContourLineThicknessesScale = 2.0
    
96.         contour_tc = wrf_contour(a,wks,tc_plane,opts)
    
97.         delete(opts)
    
98. 
    
99. 
    
100.       ; Plotting options for RH               
     
101.         opts = res                          
     
102.         opts@cnFillOn = True  
     
103.         opts@ContourParameters = (/ 10., 90., 10./)
     
104.         opts@cnFillColors = (/"White","White","White", \
     
105.                               "White","Chartreuse","Green",\
     
106.                               "Green3","Green4", \
     
107.                               "ForestGreen","PaleGreen4"/)
     
108.         contour_rh = wrf_contour(a,wks,rh_plane,opts)
     
109.         delete(opts)
     
110. 
     
111. 
     
112.       ; Plotting options for Wind Vectors                 
     
113.         opts = res         
     
114.         opts@FieldTitle = "Wind"   ; overwite Field Title
     
115.         opts@NumVectors = 12       ; density for wind barbs
     
116.         vector = wrf_vector(a,wks,u_plane,v_plane,opts)
     
117.         delete(opts)
     
118. 
     
119. 
     
120.       ; Plotting options for Geopotential Heigh
     
121.         opts_z = res                          
     
122.         opts_z@cnLineColor = "Blue"
     
123.         opts_z@gsnContourLineThicknessesScale = 3.0
     
124. 
     
125. 
     
126. 
     
127.       ; MAKE PLOTS                                       
     
128.        if ( pressure .eq. 1000 ) then    ; plot temp, rh, height, wind barbs
     
129.           opts_z@ContourParameters = (/ 20.0 /)
     
130.           contour_height = wrf_contour(a,wks, z_plane,opts_z)
     
131.           plot = wrf_map_overlays(a,wks,(/contour_rh,contour_tc,contour_height, \
     
132.                                     vector/),pltres,mpres)
     
133.         end if
     
134.         if ( pressure .eq. 850 ) then    ; plot temp, rh, height, wind barbs
     
135.           opts_z@ContourParameters = (/ 20.0 /)
     
136.           contour_height = wrf_contour(a,wks, z_plane,opts_z)
     
137.           plot = wrf_map_overlays(a,wks,(/contour_rh,contour_tc,contour_height, \
     
138.                                     vector/),pltres,mpres)
     
139.         end if
     
140. 
     
141.         if ( pressure .eq. 700 ) then    ; plot temp, height, wind barbs
     
142.           opts_z@ContourParameters = (/ 30.0 /)
     
143.           contour_height = wrf_contour(a,wks, z_plane,opts_z)
     
144.           plot = wrf_map_overlays(a,wks,(/contour_tc,contour_height, \
     
145.                                     vector/),pltres,mpres)
     
146.         end if
     
147. 
     
148.         if ( pressure .eq. 500 ) then    ; plot temp, height, wind barbs
     
149.           opts_z@ContourParameters = (/ 60.0 /)
     
150.           contour_height = wrf_contour(a,wks, z_plane,opts_z)
     
151.           plot = wrf_map_overlays(a,wks,(/contour_tc,contour_height, \
     
152.                                     vector/),pltres,mpres)
     
153.         end if
     
154. 
     
155.         if ( pressure .eq. 300 ) then    ; plot temp, height, wind barbs
     
156.           opts_z@ContourParameters = (/ 60.0 /)
     
157.           contour_height = wrf_contour(a,wks, z_plane,opts_z)
     
158.           plot = wrf_map_overlays(a,wks,(/contour_tc,contour_height, \
     
159.                                     vector/),pltres,mpres)
     
160.         end if
     
161. 
     
162.         if ( pressure .eq. 100 ) then    ; plot temp, height, wind barbs
     
163.           opts_z@ContourParameters = (/ 15840.,16380.,60.0 /)
     
164.           contour_height = wrf_contour(a,wks, z_plane,opts_z)
     
165.           plot = wrf_map_overlays(a,wks,(/contour_tc,contour_height, \
     
166.                                     vector/),pltres,mpres)
     
167.         end if
     
168.         delete(opts_z)
     
169. 
     
170.     end do      ; END OF LEVEL LOOP
     
171. 
     
172. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
     
173. 
     
174.   end do        ; END OF TIME LOOP
     
175. 
     
176. end

复制代码

0708011

应该是1000hpa没有数据 地表气压已经低于1000hpa了。你可以画画925试试。我有时候925hpa也出现空白区。