回归系数显著性检验

youngman

1. f     = addfile("/mnt/e/DATA/Data_Draw/sst-197901-201501.nc", "r")
   
2. sst   = f->sst
   
3. time  = sst&time
   
4. ;------------------ regression -------------------
   
5. rc    = regCoef_n(time, sst, 0, 0)
   
6. ;--------------------- test ----------------------
   
7. tval = onedtond(rc@tval , dimsizes(rc))  ;t统计量
   
8. tval@_FillValue = -32767       ;Attention: tval had no info~
   
9. df   = onedtond(rc@nptxy,dimsizes(rc))-2 ;自由度
   
10. b    = new((/dimsizes(sst(0,:,0)),dimsizes(sst(0,0,:))/),float)
    
11. b    = 0.5
    
12. prob = 1-betainc(df/(df+tval^2), df/2.0, b)
    
13. ;-------------------------------------------------
    
14. copy_VarCoords(sst(0,:,:), prob)
    
15. rc = rc*100000
    
16. copy_VarCoords(sst(0,:,:), rc)
    
17. 
    
18. 
    
19. wks  = gsn_open_wks("x11", "regress")
    
20. res                         = True
    
21. res@gsnMaximize             = True
    
22. res@gsnAddCyclic            = True
    
23. res@gsnDraw                 = False
    
24. res@gsnFrame                = False
    
25. res@gsnLeftString           = ""
    
26. res@gsnRightString          = ""
    
27. res@cnFillOn                = True
    
28. res@cnLinesOn               = False
    
29. res@cnLineLabelsOn          = False
    
30. res@cnInfoLabelOn           = False
    
31. res2 = res
    
32. res@cnLevelSelectionMode    = "ExplicitLevels"
    
33. res@cnLevels                = fspan(-16,16,17)
    
34. res@mpFillOn                = False
    
35. res@mpCenterLonF            = 210
    
36. plot = gsn_csm_contour_map(wks, rc, res)
    
37. ;----------------- 显著区域打点 ------------------
    
38. res2@cnLevelSelectionMode   = "ExplicitLevels"
    
39. res2@cnLevels               = (/0.9,0.99/) ; significance level
    
40. res2@cnFillColors           = (/"white","orange","black"/)
    
41. res2@cnFillPatterns         = (/-1,17,17/)
    
42. res2@cnFillScales           = (/1,1.5,1.5/)
    
43. res2@cnFillDotSizeF         = 0.003
    
44. res2@cnMonoFillPattern      = False
    
45. res2@cnMonoFillScale        = False
    
46. res2@lbLabelBarOn           = False
    
47. plot_p = gsn_csm_contour(wks, prob, res2)
    
48. overlay(plot, plot_p)
    
49. draw(plot)
    
50. frame(wks)
    

复制代码

气象小鬼

regCoef函数里面不是自己算了一个t检验统计量，不可以直接用吗？

youngman

气象小鬼 发表于 2020-4-23 16:36
regCoef函数里面不是自己算了一个t检验统计量，不可以直接用吗？

可以用啊，这里是把它换算成了概率

气象小鬼

哦哦

TB~suo

貌似明白了一点

wsx

请问下rc = rc*100000是怎么理解啊，算出的rc是回归系数系数还是有量纲的？新生求教.

拾柒ovo

prob = 1-betainc(df/(df+tval^2), df/2.0, b)
这个地方为什么要－呢

拾柒ovo

还有b=0.5是什么意思呢