画涡度图，为什么阴影图边缘会留白。

┏_(゜ω゜)=

'reinit'
'open e:/fnl/fnl_20200519_12_00.ctl'
'enable print e:/fnl/new/vor500.gmf'
'set lon 100 125'
'set lat 15 30'  
'set mpdset cnworld'

t=1
while(t<=18)
'set t 't''
'set lev 500'


'define vor=hcurl(ugrdprs,vgrdprs)'

*-------------------------------------------------------------
'set parea 1 9.4 1 8'
*设置画布尺寸
'set xlopts 1 4 0.14'
*设置X轴标注颜色 粗细 大小
'set ylopts 1 4 0.14'

'set grid off'
'set grads off'

'set gxout shaded'



'set rgb 20 255 255 255'
'set rgb 21 181 202 255'
'set rgb 22 143 179 255'
'set rgb 23 171 207 99'
'set rgb 24 255 250 20'
'set rgb 25 255 209 33'
'set rgb 26 255 76 0'

'set rbcols 20 21 22 23 24 25 26 '
'set clevs 0 2 4 6 8 10 '


'd vor*1e5'
'run cbarn.gs'


*-------------------------------------------------------------------------------------

'set gxout barb'
'set ccolor 1'
'set bargap 50'
'set digsiz 0.05'
'set arrowhead 0.05'
*设置箭头尺寸
*'d skip(UGRDprs*2.5,2,2);skip(VGRDprs*2.5,2,2)'
'd UGRDprs*2.5;VGRDprs*2.5'

*--------------------------------------------------------------------------------------
'q dims'

rec=sublin(result,5)
recs=subwrd(rec,6)
'draw title  'recs''

'print'
'c'
t=t+1
endwhile
*-------------------------------------------------------------------------------------
'disable print'
'reinit'

hbl1021

两种方法试一试1.经纬度设置放在'd UGRDprs*2.5;VGRDprs*2.5'前，不要设置太早。2.在define前先设置一个稍大点的经纬度范围，然后在d之前再设置回需要的经纬度范围。两种方法肯定能解决这个问题。

wjy_ecnu

我感觉是因为涡度默认是用中央差分，边界没法中央差分，所以边界没有

┏_(゜ω゜)=

hbl1021 发表于 2020-10-21 20:45
两种方法试一试1.经纬度设置放在'd UGRDprs*2.5;VGRDprs*2.5'前，不要设置太早。2.在define前先设置一个稍 ...

谢谢，确实是这样

┏_(゜ω゜)=

重新更改就画出来了

'reinit'
'open e:/fnl/fnl_20200519_12_00.ctl'
'enable print e:/fnl/new/vor500.gmf'

'set mpdset cnworld'

t=1
while(t<=18)
'set t 't''
'set lev 500'


'define vor=hcurl(ugrdprs,vgrdprs)'

*-------------------------------------------------------------
'set parea 1 9.4 1 8'
*设置画布尺寸
'set xlopts 1 4 0.14'
*设置X轴标注颜色 粗细 大小
'set ylopts 1 4 0.14'

'set grid off'
'set grads off'
'set xlint 5'
'set ylint 5'
'set gxout shaded'
*'set frame on'

'set lon 100 125'
'set lat 15 30'  

'set rgb 20 255 255 255'
'set rgb 21 181 202 255'
'set rgb 22 143 179 255'
'set rgb 23 171 207 99'
'set rgb 24 255 250 20'
'set rgb 25 255 209 33'
'set rgb 26 255 76 0'

'set rbcols 20 21 22 23 24 25 26 '
'set clevs 0 2 4 6 8 10 '


'd vor*1e5'
'run cbarn.gs'


*-------------------------------------------------------------------------------------

'set gxout barb'
'set ccolor 1'
'set bargap 50'
'set digsiz 0.05'
'set arrowhead 0.05'
*设置箭头尺寸
'd skip(UGRDprs*2.5,1,1);skip(VGRDprs*2.5,1,1)'

*--------------------------------------------------------------------------------------
'q dims'

rec=sublin(result,5)
recs=subwrd(rec,6)
'draw title  'recs''

'print'
'c'
t=t+1
endwhile
*-------------------------------------------------------------------------------------
'disable print'
'reinit'

┏_(゜ω゜)=

修改后的图