利用wmbarb作一种有意思的组合图

longlivehj

目的不是秀图，而是介绍wmbarb。

在解决帖子中gsn_csm_xy时间坐标轴的求助后，楼主又提出了一个很有意思的要求：在每个数据点上面加上风向杆，指示风向和风速。尝试用gsn_vector等常用方式，都一一失败了，最后发现了wmbarb，成功化解了楼主的“刁难”！

因为wmbarb是ncl的内置过程，就不过多说明了，详情看帮助！直接上图和程序。





load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/contrib/cd_string.ncl"

begin

    units = "hours since 1-1-1 00:00:0.0"
    xbrange = tointeger(cd_inv_calendar((/1, 1/), (/1, 1/), (/12, 15/), (/12, 18/), (/0, 0/), (/0, 0/), units, 0))
    xbvalues = ispan(xbrange(0), xbrange(1), 6)
    xbvalues@units = units
    xblabels = cd_string(xbvalues, "%d.%H")

    npts = dimsizes(xbvalues)
    random = new(npts, "float")
    do i = 0, npts - 1
        random(i) = rand()
    end do

    low  = -20.0
    high = 20.0
    con  = (high - low) / 32766.0

    srand(1234)

    uwnd = new(npts, "float")
    do i = 0, npts - 1
        uwnd(i)= low + con * rand()
    end do

    srand(5678)

    vwnd = uwnd
    do i = 0, npts - 1
        vwnd(i) = low + con * rand()
    end do

    xyres = True
    xyres@gsnFrame = False

    xyres@tmXBMode = "Explicit"
    xyres@tmXBValues = xbvalues
    xyres@tmXBLabels = xblabels

    xyres@tmXBLabelFontHeightF = .01
    xyres@tmYLLabelFontHeightF = .01

    xyres@trXMinF = xbvalues(0)
    xyres@trXMaxF = xbvalues(npts - 1)

    wks = gsn_open_wks ("x11", "time_axis")
    gsn_define_colormap(wks, "amwg_blueyellowred")

    xyplot = gsn_csm_xy(wks, xbvalues, random, xyres)

    wmsetp("wdf", 1)
    wmsetp("col", 14)
    wmbarb(wks, tofloat(xbvalues), random, uwnd, vwnd)

    frame(wks)
end

freekiller

不错，美化美化是有创意的

sj势均力敌

gsn_vector肯定不能实现，楼主厉害啊！

longlivehj

sj势均力敌 发表于 2014-3-19 17:15

                               
登录/注册后可看大图

gsn_vector肯定不能实现，楼主厉害啊！

gsn_vector可以基本解决，就是风失的位置不能和数据点重合不是太好，我有效果图，要不要给你看看？

sj势均力敌

longlivehj 发表于 2014-3-19 18:39

                               
登录/注册后可看大图

gsn_vector可以基本解决，就是风失的位置不能和数据点重合不是太好，我有效果图，要不要给你看看？

这样啊，我想错了

贝頥嚫

给楼主点个赞！

BDRUSH

这幅图的内容似曾相识

abc258886

这个不错啊！！！！！！！！！！！

woyaofeixiang

学习了！一直想画这样的图，一直没思路

dataiyang

这里有疑问，查看了wmbarb该函数，这个画出来的风矢windbarb默认的应该是knots单位吧，如何改为m/s啊？？？？