新手求助

无敌泡

我是新手。WRF模式已经可以运行了。现在想用NCL把模拟地区的土地利用类型画出来。这个怎么弄呢？
请大神指教阿

longlivehj

无敌泡 发表于 2014-4-2 09:51
多谢多谢，我刚刚用ncl做了一个很简单的显示，比起您这个来，我简直弱爆了。
我要好好学习！ ...

不客气，我把代码又改了改，把国界啥的突出了一下，你看看！
呵呵，加油！

longlivehj

无敌泡 发表于 2014-4-1 22:26
好心人，我还是弄个简单的吧。就是把区域里的土地利用类型画出来，就可以的。可以给我一个简单的脚本我看 ...

http://www.mmm.ucar.edu/wrf/OnLi ... CL/NCL_examples.htm
上面链接里有很多非常实用的例子。我也是在其中一个基础上稍作修改，就可以作出你要的图。



下面是我整理过的代码，贴出来供你参考。


;   Example script plots all data in a geo_em file
;   November 2008

load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/wrf/WRFUserARW.ncl"

begin
  a = addfile("./geo_em.d01.nc","r")   ; Open a file
  v = a->LU_INDEX        ; Read the variable to memory

  type = "png"
; type = "pdf"
; type = "ps"
; type = "ncgm"
  wks = gsn_open_wks(type,"landuse")       ; Create a plot workstation
  gsn_define_colormap(wks,"StepSeq25")

  mpres = True                             ; Set map options
  mpres@mpGeophysicalLineColor = "Black"
  mpres@mpGeophysicalLineThicknessF = 2.
  mpres@mpOutlineBoundarySets = "National"
  mpres@mpNationalLineColor    = "Black"
  mpres@mpNationalLineThicknessF = 2

  opts = True                               ; Set some Basic Plot options
  opts@InitTime = False                     ; Do not plot time or footers
  opts@Footer = False
  opts@cnFillOn = True
  opts@cnFillMode       = "RasterFill"
  opts@cnExplicitLabelBarLabelsOn = True
  opts@ContourParameters = (/ 2,24,1 /)
  opts@lbLabelStrings = (/ "Urban and Built-Up Land", "Dryland Cropland and Pasture", \
                           "Irrigated Cropland and Pasture", "Mixed Dryland/Irrigated Cropland", \
                           "Cropland/Grassland Mosaic", "Cropland/Woodland Mosaic", "Grassland", \
                           "Shrubland", "Mixed Shrubland/Grassland", "Savanna", \
                           "Deciduous Broadleaf Forest", "Deciduous Needleleaf Forest", \
                           "Evergreen Broadleaf Forest", "Evergreen Needleleaf Forest", \
                           "Mixed Forest", "Water Bodies", "Herbaceous Wetland", "Wooded Wetland", \
                           "Barren or Sparsely Vegetated", "Herbaceous Tundra", "Wooded Tundra", \
                           "Mixed Tundra", "Bare Ground Tundra", "Snow or Ice" /)
  opts@lbLabelAngleF = 270.0
  opts@lbLabelAlignment = "BoxCenters"
  opts@lbTitleOn = False
  opts@lbLabelFontHeightF = 0.01
  opts@lbLabelJust = "CenterLeft"
  opts@pmLabelBarOrthogonalPosF = 0.01
  opts@FieldTitle = "LU_INDEX : "+ v@description   ; overwrite field name

  contour = wrf_contour(a,wks,v(0,:,:),opts)
  plot = wrf_map_overlays(a,wks,(/contour/),True,mpres)
end

longlivehj

在geogrid.exe的输出文件geo_em.d01.nc中有两个变量与土地利用类型有关。
1. LANDUSEF 各类型所占比例
2. LU_INDEX 比例最大的类型

用ncl提取变更量做图就好了，等值线图，用RasterFill。

无敌泡

longlivehj 发表于 2014-4-1 21:31
在geogrid.exe的输出文件geo_em.d01.nc中有两个变量与土地利用类型有关。
1. LANDUSEF 各类型所占比例
2. ...

谢谢 我试试阿。

无敌泡

longlivehj 发表于 2014-4-1 21:31
在geogrid.exe的输出文件geo_em.d01.nc中有两个变量与土地利用类型有关。
1. LANDUSEF 各类型所占比例
2. ...

我弄的一塌糊涂。我就是想让土地利用类型一起出现在show namelist.wps里面。这么难阿

longlivehj

无敌泡 发表于 2014-4-1 22:13
我弄的一塌糊涂。我就是想让土地利用类型一起出现在show namelist.wps里面。这么难阿

不太明白什么意思啊！

无敌泡

longlivehj 发表于 2014-4-1 22:19
不太明白什么意思啊！

好心人，我还是弄个简单的吧。就是把区域里的土地利用类型画出来，就可以的。可以给我一个简单的脚本我看看么？多谢多谢

Wuchuanhao

看看，帮顶。。。

无敌泡

longlivehj 发表于 2014-4-2 09:25
http://www.mmm.ucar.edu/wrf/OnLi ... CL/NCL_examples.htm
上面链接里有很多非常实用的例子。我也是在 ...

多谢多谢，我刚刚用ncl做了一个很简单的显示，比起您这个来，我简直弱爆了。
我要好好学习！谢谢您！