NCL代码分享-MICAPS第四类数据转NetCDF文件

liuxiaoyue

直接上代码，以2017年10月8日20时海平面气压场（附件）为例。

begin

    ; read data
    lines = asciiread("17100820.000",-1,"string")
    delim = " "
    print("header:")
    print(lines(1:3))

    ; coordinate information
    dlon = tofloat(str_get_field(lines(2),1,delim))
    dlat = -tofloat(str_get_field(lines(2),2,delim))

    nlon = toint(str_get_field(lines(3),1,delim))
    nlat = toint(str_get_field(lines(3),2,delim))

    minlon = toint(str_get_field(lines(2),3,delim))
    maxlon = toint(str_get_field(lines(2),4,delim))

    minlat = toint(str_get_field(lines(2),6,delim))
    maxlat = toint(str_get_field(lines(2),5,delim))

    print("dlon   = " + dlon   + "; dlat   = " + dlat)
    print("nlon   = " + nlon   + "; nlat   = " + nlat)
    print("minlon = " + minlon + "; maxlon = " + maxlon)
    print("minlat = " + minlat + "; maxlat = " + maxlat)

    lat = fspan(maxlat, minlat, nlat)
    lat@units = "degrees_north"
    lon = fspan(minlon, maxlon, nlon)
    lon@units = "degrees_east"
   
    ; prepare array
    p0 = new((/dimsizes(lat),dimsizes(lon)/), float)
    p0!0 = "lat"
    p0&lat = lat
    p0!1 = "lon"
    p0&lon = lon
   
    ; convert
    do i = 0, nlat-1
        n = 8*i+4
        p0(i,{ispan(minlon, maxlon, 10)}) = tofloat(str_get_field(lines(n:n+7),1,delim))
        do j = 1, 9
            p0(i,{ispan(minlon+j, maxlon-10+j, 10)}) = tofloat(str_get_field(lines(n:n+6),j+1,delim))
        end do
    end do
   
    ; output
    system("/bin/rm -f p0.17100820.nc")
    ncdf = addfile("p0.17100820.nc","c")
    ncdf->p0 = p0

end

Уēｓ、尜玉

你真是太太优秀了！！！！{:5_213:}{:5_213:}

liuxiaoyue

Уēｓ、尜玉 发表于 2019-7-25 19:46
你真是太太优秀了！！！！

{:5_257:}{:5_257:}

戏子丶

优秀，up可以继续研究下，其他的格式的数据转为NC的

sunflower

超级棒！！！！！！！

Summer0456

请问一下楼主，为什么dlon = tofloat(str_get_field(lines(2),1,delim)), 而dlat = -tofloat(str_get_field(lines(2),2,delim)) ，这是什么意思？ dlat是负的？

liuxiaoyue

Summer0456 发表于 2019-8-8 12:53
请问一下楼主，为什么dlon = tofloat(str_get_field(lines(2),1,delim)), 而dlat = -tofloat(str_get_field ...

对的，dlat就是负的，micaps数据是由北至南，从高纬向低纬度的。
所以在定义纬度的时候：
lat = fspan(maxlat, minlat, nlat)

padapong

yueyue真棒

花树下的喵

请问楼主还在么。 p0(i,{ispan(minlon, maxlon, 10)}) = tofloat(str_get_field(lines(n:n+7),1,delim))这个语句，10是数据列数，7是行数是么？我直接改成了我自己数据的行列，n也改了，但是报错说等号左右不匹配，请问是什么原因呢

slchengh

楼主，你这个没看到时间维度的设定呀