关于降水资料脚本

BDRUSH

这是我将站点降水资料转换为格点数据的脚本，其中大部分参考了http://blog.sina.com.cn/s/blog_44f7c0840100on44.html，然后运行一段时间之后就被killed了，这是为什么啊，是不是脚本写错了，大家帮忙看看@longlivehj
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"  
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/shea_util.ncl"
begin
  fname = "13100808.000"
  a = asciiread("/home/student/zengk/data/"+fname,-1,"string")
  b = a(15::)
  delim = " "
  lon = stringtofloat(str_get_field(b,2,delim))
  lat = stringtofloat(str_get_field(b,3,delim))
  pre = stringtofloat(str_get_field(b,5,delim))

  olon = ispan(112,128,1)
  olat = ispan(23,35,1)
  
  olon!0          = "lon"
  olon@long_name  = "lon"
  olon@units      = "degrees-east"
  olon&lon        = olon
  olat!0          = "lat"
  olat@long_name  = "lat"
  olat@units      = "degrees_north"
  olat&lat        = olat
  
  pre@_FillValue = 999999.000000
  rscan = (/5,3,1/)   ;连续的有效半径大小，最大为10，依次递减
  result = obj_anal_ic_deprecated(lon,lat,pre,olon,olat,rscan,False)  ;Creanm插值
  
  wks = gsn_open_wks("pdf","ceshi")
  setvalues NhlGetWorkspaceObjectId()
    "wsMaximumSize" : 300000000
  end setvalues
  
  res = True
  res@gsnAddCyclic  = False  
  res@mpDataSetName         = "Earth..4"   ; This new database contains
                                           ; divisions for other countries.
  res@mpDataBaseVersion     = "MediumRes"  ; Medium resolution database
  
  res@mpOutlineOn           = True         ; Turn on map outlines
  res@mpOutlineSpecifiers   = (/"China:states","Taiwan"/)
  res@mpLimitMode="LatLon"
  res@mpCenterLonF=120
  res@mpMinLatF=23
  res@mpMaxLatF=35
  res@mpMinLonF=112
  res@mpMaxLonF=128
  res@mpGeophysicalLineColor = "Black"
  res@mpNationalLineColor    = "Black"
  res@mpUSStateLineColor     = "Black"

  res@mpLimbLineColor        = "Black"
  res@mpPerimLineColor       = "Black"

  res@cnFillOn      = True
  res@cnLinesOn     = False          ;等值线不显示
  res@cnLineLabelsOn = False
  res@cnFillDrawOrder = "PreDraw"         ; draw contours first   
  res@cnLevelSelectionMode = "ExplicitLevels"       ; set explicit contour levels
  res@cnLevels    = (/1,5,10,25,50,100,150,200/)            ; set levels
  res@cnFillColors =(/"White","DarkOliveGreen1","DarkOliveGreen3","Chartreuse","Green","ForestGreen","Yellow","Orange","Red"/)  ;"Chartreuse3"在"Chartreuse"与"Green"之间
  
  res@lbLabelBarOn = True
  res@lbOrientation = "Horizontal"
  
  res@vpXF = 0     ;左边距
  res@vpYF = 0.95      ;上边距
  res@vpWidthF  = 1.0              ; height and width of plot
  res@vpHeightF = 0.8
  
  map = gsn_csm_contour_map(wks,result,res)

end  

BDRUSH

longlivehj

能把数据发一份上来不？

longlivehj

另外，注意到你的ncl版本是5.2.1，5.2.0之后有改进的obj_anal_ic和相应的obj_anal_ic_Wrap。最好不要再用obj_anal_ic_deprecated，“deprecated”！

BDRUSH

longlivehj 发表于 2014-3-27 13:09
能把数据发一份上来不？

13100808.000 (26.31 KB, 下载次数: 17)

2014-3-27 15:56 上传

点击文件名下载附件
另外根据你的提示，我将插值方法修改成了data1 = obj_anal_ic(lon,lat,pre,olon,olat,rscan,False)  
但是出现了如下，该怎么修改

longlivehj

BDRUSH 发表于 2014-3-27 15:58
另外根据你的提示，我将插值方法修改成了data1 = obj_anal_ic(lon,lat,pre,olon,olat,rscan,False)  
...

我用你的程序，不做修改，可以出图。

用obj_anal_ic_Wrap就不会出现坐标的问题了。

BDRUSH

这种图正常不？

BDRUSH

longlivehj 发表于 2014-3-27 16:36
我用你的程序，不做修改，可以出图。

用obj_anal_ic_Wrap就不会出现坐标的问题了。

你帮我看看出图算正常不

longlivehj

BDRUSH 发表于 2014-3-27 16:48
你帮我看看出图算正常不

嗯，我这边做出来跟你贴出的差不多，不过丑多了。你后来又修改了不少吧！

BDRUSH

longlivehj 发表于 2014-3-27 17:01
嗯，我这边做出来跟你贴出的差不多，不过丑多了。你后来又修改了不少吧！

对啊，先出图再细节修改，不过我好像跟别人做的实况比对，发现并不是很匹配