WRF模拟数据结果，画图添加底图出错，求助！

zq200866

warning:mpDataBaseVersion is not a valid resource in plt_Cloud_contour at this time
warning:mpDataSetName is not a valid resource in plt_Cloud_contour at this time
warning:mpOutlineOn is not a valid resource in plt_Cloud_contour at this time
我用的是NCL6.0，更新到最新版可以解决这个问题吗？

longlivehj

只是warning，告诉你一些source当前不起作用，不是版本问题！
最好能把程序贴出来。

天心云

第一个时次的数据不要用

woyaofeixiang

这几个参数对绘图函数不起作用 你可以看看wrf官网上提供的例子http://www.mmm.ucar.edu/wrf/OnLi ... CL/NCL_examples.htm

zq200866

longlivehj 发表于 2014-3-30 14:28
只是warning，告诉你一些source当前不起作用，不是版本问题！
最好能把程序贴出来。

load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/wrf/WRFUserARW.ncl"

begin
; The WRF ARW input file.  
; This needs to have a ".nc" appended, so just do it.
  a = addfile("wrfout_d03_2012-01-13_12:00:00.nc","r")            

; We generate plots, but what kind do we prefer?
  type = "png"
; type = "pdf"
; type = "ps"
; type = "ncgm"
  wks = gsn_open_wks(type,"plt_Cloud")
  gsn_define_colormap(wks,"WhViBlGrYeOrRe")   ; overwrite the .hluresfile color map
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; Set some basic resources
  res = True
  res@MainTitle = "REAL-TIME WRF"

  pltres = True ; Plot resources
  mpres  = True  ; Map resources
  mpres@mpGeophysicalLineColor = "Black"
  mpres@mpNationalLineColor    = "Black"
  mpres@mpUSStateLineColor     = "Black"
  mpres@mpGridLineColor        = "Black"
  mpres@mpLimbLineColor        = "Black"
  mpres@mpPerimLineColor       = "Black"

      

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; First get the variables we will need        

    if(isfilevar(a,"QCLOUD"))
      qc = wrf_user_getvar(a,"QCLOUD",8)
      qc = qc*1000.
      qc@units = "g/kg"   
    end if
   

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

    do level = 0,28,1      ; LOOP OVER LEVELS

      display_level = level + 1
      opts = res


      opts@cnFillOn         = True
      opts@cnLinesOn        = True
      opts@cnLineLabelsOn   = True
      ;opts@gsnAddCyclic  = False
      opts@mpDataSetName         = "Earth..4"
      opts@mpDataBaseVersion     = "HighRes"
      opts@mpOutlineOn           = True
      opts@mpOutlineBoundarySets = "AllBoundaries"

      opts@cnLineLabelFontColor = "red"
      opts@cnLineLabelFontHeightF = 0.012
      opts@cnLineLabelBackgroundColor = "white"
      opts@PlotLevelID      = "Eta Level  " + display_level

   

      if (isvar("qc"))
        contour = wrf_contour(a,wks,qc(level,:,:),opts)
        ;opts@ContourParameters = (/ 0.02, 0.4, 0.02/)
        plot = wrf_map_overlays(a,wks,(/contour/),pltres,mpres)
        delete(contour)
      end if

     

      delete(opts)

    end do      ; END OF LEVEL LOOP

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

end

zq200866

longlivehj 发表于 2014-3-30 14:28
只是warning，告诉你一些source当前不起作用，不是版本问题！
最好能把程序贴出来。

程序已经贴出来了，求指导！

longlivehj

zq200866 发表于 2014-3-30 23:02
程序已经贴出来了，求指导！

      opts@mpDataSetName         = "Earth..4"
      opts@mpDataBaseVersion     = "HighRes"
      opts@mpOutlineOn           = True
      opts@mpOutlineBoundarySets = "AllBoundaries"

把这四行的中的opts全部改成mpres就可以了。
另外，看到你的mpDataBaseVesion设置的HighRes，这个地图库需要单独下载。如果还没有下载，会出现一些警告，并且地图出不来。这时要么设置成中、低分辨率，要么下载相应地图。具体信息可以看看ncl官网关于mpDataBaseVersion的帮助。

zq200866

longlivehj 发表于 2014-3-31 08:50
opts@mpDataSetName         = "Earth..4"
      opts@mpDataBaseVersion     = "HighRes"
      ...

我试试，谢谢回复！