ncl中如何实现参考风矢量的圆盘表现形式？

sun_shine_Xia

看到一篇文献中有一张图（如截图所示），这张图中是用风场来表示最高蒸发量所出现的月份，如正南风表示12月，正西风表示3月， 风向盘如图中右下角所示！那在NCL中如何画出的这个风场的指向盘呢？grads能实现吗？我现在画出了风场，但是不知道怎么添加这个参照矢量，一天下来百思不得骑姐~遂来问问论坛里面的同僚们了

longlivehj

sun_shine_Xia 发表于 2014-4-21 10:21
恩，不错，按照这个就画出来！！！膜拜~~还有个问题，他这个箭头的类型能设置吗？我研究了下wmsetp，wmve ...

给你一个另外的实现方式，供参考！
这个用到了gsn_csm_vector，可以比较灵活地控制箭头的属性。之前用wmvectmap的版本，正如你说的，箭头好像是没有太好的办法进行更改。



load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"

begin
    lat = -30.
    lon = 90.

    len = .04

    fonthgt = .015

    wks = gsn_open_wks("png", "dir")

; map
    mapres = True
    mapres@gsnDraw = False
    mapres@gsnFrame = False

    plot = gsn_csm_map(wks, mapres)

; arrows
    u = (/(/0., 0., 0./), (/-10, 0., 10./), (/0., 0., 0./)/)
    v = (/(/0., 10., 0./), (/0., 0., 0./), (/0., -10., 0./)/)

    lat2 = lat + (/.01, 0., -.01/)
    lat2@units = "degrees_north"
    lon2 = lon + (/-.01, 0., .01/)
    lon2@units = "degrees_east"

    u!0 = "lat"
    u!1 = "lon"
    u&lat = lat2
    u&lon = lon2
    copy_VarCoords(u, v)

    vectres = True
    vectres@gsnDraw = False
    vectres@gsnFrame = False
    vectres@vcGlyphStyle = "FillArrow"
    vectres@vcFillArrowEdgeColor = "black"
    vectres@vcPositionMode = "ArrowTail"
    vectres@vcRefMagnitudeF = 10.
    vectres@vcRefLengthF = len * .9
    vectres@vcRefAnnoOn = False
    vectplot = gsn_csm_vector(wks, u, v, vectres)

    overlay(plot, vectplot)
    draw(plot)

; text
    xout = 0.
    yout = 0.
    datatondc(plot, lon, lat, xout, yout)

    len2 = len * 1.1

    txtres = True
    txtres@txFontHeightF = fonthgt
    txtres@txJust = "CenterLeft"
    gsn_text_ndc(plot, "3", xout + len2, yout, txtres)
    txtres@txJust = "TopCenter"
    gsn_text_ndc(plot, "6", xout, yout - len2, txtres)
    txtres@txJust = "CenterRight"
    gsn_text_ndc(plot, "9", xout - len2, yout, txtres)
    txtres@txJust = "BottomCenter"
    gsn_text_ndc(plot, "12", xout, yout + len2, txtres)

; circle
    rad = atan(1.0) / 45.
    npts = 361
    xcirc = new(npts, float)
    ycirc = xcirc
    xcirc = xout + len * cos(fspan(0, 360, npts) * rad)
    ycirc = yout + len * sin(fspan(0, 360, npts) * rad)

    gsn_polyline_ndc(wks, xcirc, ycirc, False)

    frame(wks)

end

longlivehj

简单写了个示例，供你参考！
程序中头几行，lat和lon用于设定圆盘中心经纬度，len用于设定圆盘半径（NDC坐标，箭头长度会同步变化），fonthgt设置圆盘周围数字大小（NDC坐标）。

load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"

begin
    lat = -30.
    lon = 90.

    len = .04

    fonthgt = .015

    wks = gsn_open_wks("png", "dir")

; map
    mapres = True
    mapres@gsnFrame = False

    plot = gsn_csm_map(wks, mapres)

; arrows
    u = (/10., 0., 0., -10./)
    v = (/0., 10., -10., 0./)

    latin = new(4, "float")
    lonin = latin
    latin(:) = lat
    lonin(:) = lon

    wmsetp("vrn", len)
    wmvectmap(wks, latin, lonin, u, v)

; text
    xout = 0.
    yout = 0.
    datatondc(plot, lon, lat, xout, yout)

    txtres = True
    txtres@txFontHeightF = fonthgt
    txtres@txJust = "CenterLeft"
    gsn_text_ndc(plot, "3", xout + len, yout, txtres)
    txtres@txJust = "TopCenter"
    gsn_text_ndc(plot, "6", xout, yout - len, txtres)
    txtres@txJust = "CenterRight"
    gsn_text_ndc(plot, "9", xout - len, yout, txtres)
    txtres@txJust = "BottomCenter"
    gsn_text_ndc(plot, "12", xout, yout + len, txtres)

; circle
    rad = atan(1.0) / 45.
    npts = 361
    xcirc = new(npts, float)
    ycirc = xcirc
    xcirc = xout + len * cos(fspan(0, 360, npts) * rad)
    ycirc = yout + len * sin(fspan(0, 360, npts) * rad)

    gsn_polyline_ndc(wks, xcirc, ycirc, False)

    frame(wks)

end

沙颖凯

原图的罗盘很简陋，看上去不像程序自动生成的，个人猜想是后期处理时补上去的，我只知道MATLAB和ArcGIS有类似的东西，LZ完全可以自己画一个在上面

sun_shine_Xia

沙颖凯 发表于 2014-4-20 16:51
原图的罗盘很简陋，看上去不像程序自动生成的，个人猜想是后期处理时补上去的，我只知道MATLAB和ArcGIS有类 ...

我也觉得后期处理一个上去很简单，要不把图里面这个截屏下来放上去也容易。但是这样担心会破坏图片的分辨率，变模糊了~

lxlxllx89

你可以自己制作 物理量的风矢量，再画出来
自己设置12个u v 分别对应12个月份的矢量格式，就行了

lxlxllx89

哦 看错问题了，圆盘只能自己花了 画4个箭头一个圆 4个数字 grads可以实现

阿木木

虽然不知道想拿点金钱可以么？

sun_shine_Xia

lxlxllx89 发表于 2014-4-20 20:47
哦 看错问题了，圆盘只能自己花了 画4个箭头一个圆 4个数字 grads可以实现

grads的话就只有一个圆，一个数字的添加了吧~四个不同指向的剪头咋画？

sun_shine_Xia

阿木木 发表于 2014-4-20 21:06
虽然不知道想拿点金钱可以么？

关键时刻莫要捣蛋~

andrewsoong

9楼太牛了~~~