求助：NCL运行滤波脚本出错

xiaocaoqiqiao

我现在要对olr资料滤波，olr资料用的是日平均的olr.day.mean.nc，学姐给了我一个滤波的脚本，我在windows系统上操作，运行出来一直显示第10行有错误，请求各位大大帮我看一下问题出在哪里了，十分感谢。
滤波脚本如下：
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"   
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"   
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"   
begin
   diri    = "/cygdrive/D/MJO/"
   vName   = "olr"        ; name of variable on the file
   fili    = "olr.day.mean.nc"
   f       = addfile(diri+fili, "r")
   x       =short2flt( f->$vName$(:,:,:));直接利用所给资料滤波，始末时间未变
printVarSummary(x)
;nlat=f->olr&lat
;nlon=f->olr&lon
;ntime=f->olr&time
;anom = x ;(lat|:,lon|:,time|:)                 ; trick to copy cv's and atts
;   anom = dim_rmvmean(x(lat|:,lon|:,time|:))
;printVarSummary(anom)
; ***********************************************
; create the filter weights and apply
; ***********************************************
   ihp     = 2                             ; band pass
   sigma   = 1.0                           ; Lanczos sigma
   nWgt    = 201                          ; loose 100 each end                           
   fca     = 1./80.                       ; start freq
   fcb     = 1./20.                        ; last  freq
   wgt     = filwgts_lanczos (nWgt, ihp, fca, fcb, sigma )


   xBPF =wgt_runave ( x(lat|:,lon|:,time|:), wgt, 0 )  ; 20-80 day
xBPF!0="lat"
xBPF!1="lon"
   xBPF!2="time"
xBPF&lat=x&lat
xBPF&lon=x&lon
xBPF&time=x&time
; ***********************************************
; create new date array for use on the plot
; ***********************************************
   date    = cd_calendar(x&time,-2)        ; yyyymmdd
   yrfrac  = yyyymmdd_to_yyyyfrac (date, 0)
   delete(yrfrac@long_name)
   delete(x@long_name)
   pStrt = 19800101      ; 画图所用4 years: winter 96-97 MJO gold standard
   pLast = 19811231
   iStrt = ind(date.eq.pStrt)        ; user specified dates
   iLast = ind(date.eq.pLast)
   delete(date)

   pltType = "ps"
   pltName = "filters"
   plot    = new ( 2, "graphic")
   wks     = gsn_open_wks (pltType,pltName)
   res              =True            ; plot mods desired
   res@gsnDraw      = False           ; don't draw
   res@gsnFrame     = False           ; don't advance frame yet      
   res@vpHeightF    = 0.4             ; change aspect ratio of plot
   res@vpWidthF     = 0.8                  
   res@vpXF         = 0.1             ; start plot at x ndc coord
   res@gsnYRefLine  = 0.0             ; create a reference line   
   
   res@gsnCenterString = "Anomaly olr [0, 120E]"
plot(0) = gsn_csm_xy (wks,yrfrac(iStrt:iLast),x(iStrt:iLast,{0},{120}),res)      
   
   res@gsnCenterString  = "Band Pass Filtered: 20-80 day"     
plot(1) = gsn_csm_xy (wks,yrfrac(iStrt:iLast),xBPF({0},{120},iStrt:iLast),res)     
   
   resP                 = True   
   resP@gsnMaximize     = True
   gsn_panel(wks,plot,(/2,1/),resP)
fout=addfile("filolr.nc","c")
filedimdef(fout,"time",-1,True)
fout->olrfil=xBPF(time|: ,lat|:,lon|:)
end

夏夜

找到这五个参数的解释了：http://www.ncl.ucar.edu/Document ... lwgts_lanczos.shtml

longlivehj

你注意一下，错误提示里面有个nclmalloc failed，分配内存失败了。这跟你用cygwin和32bit ncl有关，数据超过2GB了。

xiaocaoqiqiao

longlivehj 发表于 2014-5-2 21:38
你注意一下，错误提示里面有个nclmalloc failed，分配内存失败了。这跟你用cygwin和32bit ncl有关，数据超 ...

所以我不能在windows上通过cygwin操作ncl，而是要在linux系统上用？

longlivehj

可不可以只读局部区域数据？现在你做的是全球的。

xiaocaoqiqiao

longlivehj 发表于 2014-5-3 11:00
可不可以只读局部区域数据？现在你做的是全球的。

谢谢你啊，的确是内存的问题，换个window 8系统的版本就能运行出来了

夏夜

请问LZ，
  ihp     = 2                             ; band pass
   sigma   = 1.0                           ; Lanczos sigma
   nWgt    = 201                          ; loose 100 each end   
这三个参数在做滤波时是不是不用改变了，只需要改变fca和fcb？

在ncl官网上看到（http://www.ncl.ucar.edu/Applications/Scripts/filters_3.ncl）也是这样，这个三个参数的设置和所用的数据有没有什么关联？
非常感谢

philo~world

楼主， xBPF =wgt_runave ( x(lat|:,lon|:,time|:), wgt, 0 )  ; 20-80 day
xBPF!0="lat"
xBPF!1="lon"
   xBPF!2="time"
xBPF&lat=x&lat
xBPF&lon=x&lon
xBPF&time=x&time
这句什么意思啊？
xBPF是滤波后的数据吧，为什么要把原始数据在赋值给xBPF呢？

xiaocaoqiqiao

philo~world 发表于 2015-3-16 11:55
楼主， xBPF =wgt_runave ( x(lat|:,lon|:,time|:), wgt, 0 )  ; 20-80 day
xBPF!0="lat"
xBPF!1="lon"

是把原始数据的经纬度信息赋给xBPF

philo~world

xiaocaoqiqiao 发表于 2015-3-16 13:56
是把原始数据的经纬度信息赋给xBPF

唉？可是这样会不会改变xBPF的值呢？
xBPF&lat=x&lat
xBPF&lon=x&lon
xBPF&time=x&time
我感觉这是赋值语句。。。。除了把经纬度信息给了xBPF,x的数据信息不会也给了xBPF么？