站点画图出错

我就是-猴子

;;;;;;;;;;read data;;;;;;;;;;;;;;;;;
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"                                                                                                                  
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"                                                                                                                  
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"                                                                                                               
load "$NCARG_ROOT/lib/ncarg/nclscripts/cnmap/cnmap.ncl"

begin   
   a = asciiread ("china.txt",(/2340,4/), "float")                                                                                                                          
   lat = a(:,0)                                                                                                                                                            
   lon = a(:,1)                                                                                                                                                            
   pre10 = a(:,2)
   pre5 = a(:,3)
   
;;;cressman;;;;;;;;
  olon=new(66,"float");
  olat=new(66,"float");
  data1=new((/66,66/),"float");
  do i=0,65
   olon(i)=72+i
  end do
  do j=0,65
   olat(j)=17+j
  end do
  
;;;;;设置属性，符合netcdf规定的数据格式;;;;;;;;
  olon!0        ="lon"
  olon@long_name="lon"
  olon@units    ="degrees-east"
  olon&lon      =olon
  olat!0        ="lat"
  olat@long_name="lat"
  olat@units    ="degrees-north"
  olat&lat      =olat
  
; R@_FillValue=-9999
rscan=(/10,5,3/)
data1=obj_anal_ic_Wrap(lon,lat,pre10,olon,olat,rscan,True);creanm插值
;data1=linint2_points(lon,lat,pre10,True,olon,olat,0)

wks = gsn_open_wks("png","china")
gsn_define_colormap(wks,"gui_default")

res=True
res@gsnDraw                 =False
res@gsnFrame                =False
res@mpMinLatF               = 17.                        
res@mpMaxLatF               = 55.
res@mpMinLonF               = 72.
res@mpMaxLonF               = 136.

res@mpFillOn                = True
res@mpOutlineOn             = False  ; Use outlines from shapefile
res@cnFillDrawOrder         = "PreDraw"
res@mpDataBaseVersion       = "MediumRes"
res@mpDataSetName           = "Earth..4"
res@mpAreaMaskingOn         = True
res@mpMaskAreaSpecifiers    = (/"China","Taiwan","Disputed area between India and China","India:Arunachal Pradesh"/)
res@mpLandFillColor         = "white"
res@mpInlandWaterFillColor  = "white"
res@mpOceanFillColor        = "white"
res@mpOutlineBoundarySets   = "NoBoundaries"
;>--------------------------------------------<
; set for the plot

res@cnFillOn                = True               
res@cnLinesOn               = False            
; res@cnLevelSpacingF         = 5.            
res@gsnSpreadColors         = True         
res@lbLabelAutoStride       = True               
map=gsn_csm_contour_map(wks,data1,res)

;>============================================================<
;                      add China map
;>------------------------------------------------------------<
cnres           = True
cnres@china     = True       ;draw china map or not
cnres@river     = True       ;draw changjiang&huanghe or not
cnres@province  = True       ;draw province boundary or not
cnres@nanhai    = True       ;draw nanhai or not
cnres@diqu      = False       ; draw diqujie or not

chinamap = add_china_map(wks,map,cnres)
;>============================================================<

draw(map)
frame(wks)
end  

我就是-猴子

提示这样的错误
(0)     gsn_add_cyclic: Warning: The range of your longitude data is not 360.
(0)     You may want to set gsnAddCyclic to False to avoid a warning
(0)     message from the spline function.
warning:_NhlCreateSplineCoordApprox: Attempt to create spline approximation for X axis failed: consider adjusting trXTensionF value
warning:IrTransInitialize: error creating spline approximation for trXCoordPoints; defaulting to linear

请教高手是怎么回事啊

longlivehj

(0)     You may want to set gsnAddCyclic to False to avoid a warning

張顧.煒Zane

res@gsn_add_cyclic=False

我就是-猴子

longlivehj 发表于 2015-1-10 19:54
(0)     You may want to set gsnAddCyclic to False to avoid a warning

谢谢您的答复

我就是-猴子

張顧.煒Zane 发表于 2015-1-22 13:40
res@gsn_add_cyclic=False

谢谢您的帮组