求助～设置兰伯特投影后限定区域经纬度显示有问题

zzzzzx

格点dat资料画图时选择兰伯特投影后限定画图区域后经纬度显示有问题，不知道问题在哪，还请各位帮忙看下
我的ncl脚本如下：
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"

begin
   data=fbindirread("t-mon.dat", -1, (/239,163,283/), "float")
   printVarSummary(data)
  lon = fspan(69.75,140.25,283)
  lat = fspan(14.75,55.25,163)
  time = fspan(1,239,239)
  ;time = tostring(time1)
  lat!0     = "lat"
  lon!0     = "lon"
  time!0    = "time"

  lat@units = "degrees_north"
  lon@units = "degrees_east"
  time@units= "days since 1998-04-01 00:00:00"
  time@long_name = "Time"
  lat&lat   = lat
  lon&lon   = lon
  time&time   = time


  data!1 = "lat"
  data!2 = "lon"
  data!0 = "time"
  data&time = time
  data&lat = lat
  data&lon = lon
  data@_FillValue = -9999
  data@description=""
  data@units = ""

  wks_type="eps"
  wks=gsn_open_wks(wks_type,"obs-t")

  sum_t=data(66,:,:)
  ;printVarSummary(sum_t)

  res= True

  res@gsnAddCyclic = False
  res@mpDataSetName         = "Earth..4"   ; This new database contains
                                           ; divisions for other countries.
  res@mpDataBaseVersion     = "MediumRes"  ; Medium resolution database
  res@mpOutlineOn           = True         ; Turn on map outlines
  res@mpMaskAreaSpecifiers = (/"China:states","Taiwan"/)   ;China:states
  

  res@mpMinLatF             =  17          ; Asia limits
  res@mpMaxLatF             =  55
  res@mpMinLonF             =  72
  res@mpMaxLonF             = 136
  
  res@mpProjection = "LambertConformal"  ; Lambert
  res@mpLambertMeridianF = 104.06
  res@mpLimitMode = "LatLon"
  res@mpLambertParallel1F = 30      ;Default: .001
  res@mpLambertParallel2F = 60    ;Default: 89.999


res@cnFillOn=True
res@cnLinesOn=False
res@cnLineLabelsOn = False
res@cnFillDrawOrder= "PostDraw"     
res@cnInfoLabelOn=False


  res@pmTickMarkDisplayMode = "Always"
; res@tmXTOn = False
; res@tmYROn = False

  res@cnLevelSelectionMode="ExplicitLevels"
  res@cnLevels = (/8,10,12,14,16,19,20,22,24,26,28/)  


  res@lbLabelBarOn = True       ;LabelBar显示

    map = gsn_csm_contour_map(wks,sum_t,res)

end

出来的图经纬度显示很奇怪...跟我限定的区域有出入，上下坐标还不一致...

我缩小区域试了，也不对，区域设置成下面图更奇怪了...
  res@mpMinLatF             =  30  
  res@mpMaxLatF             =  31.5
  res@mpMinLonF             =  102.45
  res@mpMaxLonF             =  104.45

跟我选的区域不一致，上下坐标也不一样，真心求助阿，自己实在不明白为什么

longlivehj

有投影，这种上下坐标很正常。
楼主把网格线打开看看就明白了。

zzzzzx

longlivehj 发表于 2015-1-19 12:48
有投影，这种上下坐标很正常。
楼主把网格线打开看看就明白了。

哦，谢谢，确实忽略了这点。
但是我想把它弄成跟wrfout画出来的经纬度一致，有什么好的方法吗？限定经纬度后下方的经度横坐标与我想要的区域有出入...

longlivehj

zzzzzx 发表于 2015-1-19 13:08
哦，谢谢，确实忽略了这点。
但是我想把它弄成跟wrfout画出来的经纬度一致，有什么好的方法吗？限定经纬 ...

用Corners的方式设置范围

zzzzzx

longlivehj 发表于 2015-1-19 14:08
用Corners的方式设置范围

我设置了下，出来的是整个区域的...是哪里还需要添加设置吗
  res@mpLimitMode = "LatLon"
  res@mpLeftCornerLatF       = 17
  res@mpRightCornerLatF      = 55
  res@mpLeftCornerLonF       = 72
  res@mpRightCornerLonF      = 136

longlivehj

zzzzzx 发表于 2015-1-19 14:52
我设置了下，出来的是整个区域的...是哪里还需要添加设置吗
  res@mpLimitMode = "LatLon"
  res@mpLe ...

  res@mpLimitMode = "LatLon"

zzzzzx

longlivehj 发表于 2015-1-19 22:49
res@mpLimitMode = "LatLon"

啊，谢谢，第一次用这个，看说明的时候没注意。
现在能正常出图了，真的是非常感谢。

dataiyang

longlivehj 发表于 2015-1-19 12:48
有投影，这种上下坐标很正常。
楼主把网格线打开看看就明白了。

哈哈，我之前也出过坐标类似的问题，版主也是这么对我说的啊！哇哈哈哈

dcx

请问楼主是把res@mpLimitMode = "LatLon"去掉么