为什么画中国地图出不来南海诸岛和边线

我是小猪 · 发表于 2017-4-13 01:03:50

登录后查看更多精彩内容~

您需要登录才可以下载或查看，没有帐号？立即注册

x

http://bbs.06climate.com/forum.p ... &extra=page%3D1 仿照兰溪大神 “快速绘制准确中国地图，值得你拥有！”的帖子，基本没怎么修改，但是怎么也出不来南海诸岛，很奇怪

load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"
load "/disk1/dzz/cnmap/cnmap.ncl"
begin
f=addfile("/disk3/ncep/monthly/surface/slp.mon.mean.nc","r")
pres=f->slp(0,:,:)
;---------------------------------------------------------------
wks = gsn_open_wks("pdf","/disk1/dzz/study/ncl/EAWM/Correct_China_boundary")
gsn_define_colormap( wks ,"gui_default")
res = True
;res@gsnMaximize = True
res@gsnDraw = False
res@gsnFrame = False
;---------------------------------------------------------------
; set for the map
res@mpMinLatF = 17.
res@mpMaxLatF = 55.
res@mpMinLonF = 72.
res@mpMaxLonF = 136.
res@mpFillOn = True
res@mpOutlineOn = True
res@mpDataSetName = "Earth..4"
res@mpDataBaseVersion = "MediumRes" ; "MediumRes" ; or "Ncarg4_1"
res@mpAreaMaskingOn = True
res@mpMaskAreaSpecifiers = (/"China"/)
res@mpOutlineSpecifiers = (/"China","China:Provinces"/)
res@mpLandFillColor = "white"
res@mpInlandWaterFillColor = "white"
res@mpOceanFillColor = "white"
res@mpFillBoundarySets = "NoBoundaries"
res@mpOutlineBoundarySets = "NoBoundaries"
res@mpNationalLineColor = "black"
res@mpProvincialLineColor = "black"
res@mpGeophysicalLineColor = "black"
res@mpNationalLineThicknessF = 2
res@mpProvincialLineThicknessF = 1
;---------------------------------------------------------------
; set for the plot
res@cnFillOn = True
res@cnFillDrawOrder = "PreDraw"
res@cnLinesOn = False
;res@cnLevelSpacingF = 20.
res@gsnSpreadColors = True
res@lbLabelAutoStride = True
res@pmTickMarkDisplayMode = "Always"
res@gsnRightString = "hPa"
res@lbLabelBarOn = False
res@cnInfoLabelOn = False
res@cnLineLabelsOn = False
res@gsnLeftString = "Surface pressure over part China Map with SCS"
map = gsn_csm_contour_map_ce(wks,pres,res)
;*************************************************************
;--- add South China Sea ---
nhres = res
nhres@gsnMaximize = False
nhres@vpHeightF = 0.13
nhres@vpWidthF = 0.13
nhres@mpMinLatF = 2.0
nhres@mpMaxLatF = 23.0
nhres@mpMinLonF = 105.0
nhres@mpMaxLonF = 123.0
nhres@lbLabelBarOn = False
nhres@tmXBOn = False
nhres@tmXTOn = False
nhres@tmYLOn = False
nhres@tmYROn = False
nhres@gsnLeftString = ""
nhres@gsnRightString = ""
map_nanhai = gsn_csm_contour_map(wks,pres,nhres)
adres = True
adres@amParallelPosF = 0.5 ; -0.5 is the left edge of the plot.
adres@amOrthogonalPosF = 0.5 ; -0.5 is the top edge of the plot.
adres@amJust = "BottomRight"
plotnh = gsn_add_annotation(map,map_nanhai,adres)
;--- add Changjiang and Huanghe river ---
river = True
river@gsLineThicknessF = 2.0
river@gsLineColor = "blue"
plotrv = gsn_add_shapefile_polylines(wks,map,"/disk1/dzz/data/river.nc",river)
draw(map)
frame(wks)
;--- add City ---
city = True
city@gsLineThicknessF = 1.0
city@gsLineColor = "grey"
plotct = gsn_add_shapefile_polylines(wks,map,"/disk1/dzz/data/diquJie_polyline.nc",city)
draw(map)
frame(wks)
end

复制代码

不知道为什么，很奇怪，希望大家帮助一下，在此谢谢啦！！！

尽头的尽头 · 发表于 2017-4-13 08:24:30

本帖最后由尽头的尽头于 2017-4-13 10:05 编辑

一看你中国地图都不对，没有认真看连接下的使用方法，说的很明白要用修改后的地图文件替换掉ncl自带的地图文件

我是小猪 · 发表于 2017-4-13 12:09:21

尽头的尽头发表于 2017-4-13 08:24
一看你中国地图都不对，没有认真看连接下的使用方法，说的很明白要用修改后的地图文件替换掉ncl自带的地图 ...

喔原来是这样！！太感谢啦！我去看看粗心了

我是小猪 · 发表于 2017-4-13 12:33:23

尽头的尽头发表于 2017-4-13 08:24
一看你中国地图都不对，没有认真看连接下的使用方法，说的很明白要用修改后的地图文件替换掉ncl自带的地图 ...

太感谢了，是我没看仔细，出来了图！！

尽头的尽头 · 发表于 2017-4-13 16:56:05

我是小猪发表于 2017-4-13 12:33
太感谢了，是我没看仔细，出来了图！！

不客气。解决了就好

yumingzhongshen · 发表于 2017-4-13 22:04:11

修改自带的地图文件呀，内置的文件要替换掉的

我是小猪 · 发表于 2017-4-13 23:22:40

yumingzhongshen 发表于 2017-4-13 22:04
修改自带的地图文件呀，内置的文件要替换掉的

是的，我之前没有看仔细

		自动登录	找回密码
密码			立即注册