请问ncl画wrfout风向图箭头疏密度怎么设置？

januaryflying

大家好，我用如下脚本画出的珠三角风向图的风向箭头很少，（wrfout文件： wrfout_d03_2015-11-01_00_00_00 (37.23 MB, 下载次数: 2)

2017-9-12 10:50 上传

点击文件名下载附件
wrfout文件 ）

珠三角风向图

，我想画出每个网格一个箭头的风向图，该如何做呢？
;----------------------------------------------------------------------
; overlay_11.ncl
;
; Concepts illustrated:
;   - Overlaying vectors and filled contours on a map
;   - Masking out particular areas in a map
;   - Subsetting a color map
;----------------------------------------------------------------------
; This script shows how to overlay contours and vectors on a map,
; but with the contours limited to specific areas, and the
; vectors not limited.
;
; The point of this script is to show how to mask contours against a
;geographical boundary, but in a way that allows them to be drawn up to
; the boundary location. This is unlike the shapefile masking examples,
;where grid points are set to missing if they fall outside a boundary,
; and hence you can get blocky features close to the boundary.
;
; The uvt.nc data file can be downloaded from:
;
; http://www.ncl.ucar.edu/Applications/Data/
;
;; This script was written by Yang Zhao (CAMS)
;; (Chinese Academy of Meteorological Sciences)
;;  email: 409360946@qq.com    Thanks you!
;;----------------------------------------------------------------------
;;Main Code;;
;
; These files are loaded by default in NCL V6.2.0 and newer
; load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
; load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
begin
;;read u,v,t from the data at 500hPa
        f = addfile("../wrfout_d03_2015-01-30_12:00:00.nc","r")
        lon=f->XLONG(0,:,:)
        lat=f->XLAT(0,:,:)
        dims=dimsizes(lon)
        xlen=dims(0)
        ylen=dims(1)
        u = f->U(0,1,0:116,0:152)
        v = f->V(0,1,0:116,0:152)
        t = f->T(0,1,0:116,0:152)
;;create plots;;
        wks = gsn_open_wks("png","overlay") ; send graphics to PNG file
;       gsn_define_colormap(wks,"BkBlAqGrYeOrReViWh200")
        res                = True
        res@gsnDraw        = False
        res@gsnFrame       = False
        res@gsnMaximize    = True
        res@tmXTOn         = False
        res@tmYROn         = False
        res@gsnLeftString  = ""
        res@gsnRightString = ""
        
;;set map;;
        mpres                             = res
        mpres@mpDataSetName               = "Earth..4"
        mpres@mpDataBaseVersion           = "MediumRes"
        mpres@mpOutlineOn                 = True
        mpres@mpOutlineSpecifiers         = (/"China:states","Taiwan"/)
        mpres@mpGeophysicalLineThicknessF = 2
        mpres@mpNationalLineThicknessF    = 2
        mpres@mpFillDrawOrder             = "PostDraw"
        mpres@mpFillOn                    = True
        mpres@mpFillAreaSpecifiers        = (/"water",       "land" /)
        mpres@mpSpecifiedFillColors       = (/"deepskyblue2","white"/)
        mpres@mpMaskAreaSpecifiers        = (/"China:states","Taiwan"/)


;;set area;;
        mpres@mpMinLatF                   = lat(0,0)
        mpres@mpMaxLatF                   = lat(xlen-1,ylen-1)
        mpres@mpMinLonF                   = lon(0,0)
        mpres@mpMaxLonF                   = lon(xlen-1,ylen-1)


;;set contour;;
        cnres                             = res
        cnres@cnFillDrawOrder             = "PreDraw"
        cnres@cnFillOn                    = True
        cnres@cnLinesOn                   = False
        cnres@pmLabelBarWidthF            = 0.4
        cnres@pmLabelBarHeightF           = 0.05
        cnres@pmLabelBarOrthogonalPosF    = 0.1
        cnres@lbLabelFontHeightF          = 0.006
        cnres@lbLabelAngleF               = 45
; Older way to subset a color map
       cnres@cnFillPalette               = "BkBlAqGrYeOrReViWh200"
       cnres@gsnSpreadColorStart         = 50
       cnres@gsnSpreadColorEnd           = 120


; Newer way to subset a color map
        cmap = read_colormap_file("BkBlAqGrYeOrReViWh200")
;        cnres@cnFillPalette               = cmap(25:120,:)

        cnres@gsnLeftString               = "Temp"
        
;;set vector;;
        res_vc                            = res
        res_vc@vcGlyphStyle               = "LineArrow"
        res_vc@vcRefMagnitudeF            = 20
        res_vc@vcLineArrowThicknessF      = 5
        res_vc@vcMinDistanceF             = 0.1
        res_vc@vcRefLengthF               = 0.03


;;wind barb resources don't apply
;      res_vc@vcGlyphStyle               = "WindBarb"
;     res_vc@vcWindBarbLineThicknessF   = 5
  ;    res_vc@vcWindBarbColor            = "Gray40"


        res_vc@vcRefAnnoOn               = True
        res_vc@vcRefMagnitudeF           = 30
        res_vc@vcRefAnnoString1          = "30"
        res_vc@vcRefAnnoSide             = "Top"
        res_vc@vcRefAnnoString2On        = False
        res_vc@vcRefAnnoPerimOn          = False
        res_vc@vcRefAnnoOrthogonalPosF   = -0.12
        res_vc@vcRefAnnoParallelPosF     = 0.999
        res_vc@vcRefAnnoBackgroundColor  = "Purple"
        res_vc@vcVectorDrawOrder         = "PostDraw"
        res_vc@gsnRightString            = "Wind"
        
;;plot;;
        map     = gsn_csm_map(wks,mpres)
        contour = gsn_csm_contour(wks,t,cnres)
        vector  = gsn_csm_vector(wks,u,v,res_vc)


;;overlay filled contours and vectors on the map;;
        overlay(map,contour)
        overlay(map,vector)


;;add text;;
        txres                       = True
        txres@txFontHeightF         = 0.02
        txres@txFontColor           = "Purple"
        txres@txBackgroundFillColor = "White"
        txres@txFontOpacityF        = 0.8
        txres@txFontThicknessF      = 4.0
        dum = gsn_add_text(wks,(/vector/),"500hPa",105,52.7,txres)


;;drawing "map" will draw everything: map, contours, vectors, and text;;
        draw(map)
        frame(wks)
end

主要问题如下图

talkd

res_vc@vcMinDistanceF             = 0.01

januaryflying

talkd 发表于 2017-9-12 12:29
res_vc@vcMinDistanceF             = 0.01

谢谢您的回答，我设置过那个参数，也尝试过修改的更大些，但都无济于事，该怎么办呢？

januaryflying

talkd 发表于 2017-9-12 12:29
res_vc@vcMinDistanceF             = 0.01

我就是想让箭头更密集一些，不要那么稀疏。还有什么参数是与这个有关的吗？

talkd

januaryflying 发表于 2017-9-12 14:19
谢谢您的回答，我设置过那个参数，也尝试过修改的更大些，但都无济于事，该怎么办呢？

这个参数是越小越密

januaryflying

这个问题我找到解决方案了，如下
从wrfout文件中读取经纬度并设定
  lon = a->XLONG(0, :, :)
  lat = a->XLAT(0, :, :)
  vcres@mpLimitMode = "LatLon"
  vcres@mpMinLatF = min(lat)
  vcres@mpMaxLatF = max(lat)
  vcres@mpMinLonF = min(lon)
  vcres@mpMaxLonF = max(lon)
  vcres@vfXArray = lon
  vcres@vfYArray = lat
  vcres@gsnAddCyclic = False
标红处为问题解决重点。
就是给向量图的属性设定开启坐标系画图，并设定正确的坐标系，
使得地图图层与向量图图层坐标系吻合就可以了。

januaryflying

谢谢大神的帮助

zzwei

能不能把修改后的脚本发来参考哦下？多谢！

易烊千玺

talkd 发表于 2017-9-12 12:29
res_vc@vcMinDistanceF             = 0.01

一条很有用的信息，感谢帮助

kaiofchina

学习了{:5_275:}