NCL中两图叠加问题！！！跪求解答疑惑，谢谢大家！！！

肉粽子

脚本为：
begin
  fils = systemfunc("ls ./data/Trad*.nc")
  f = addfiles(fils,"r")
  ListSetType (f,"cat")
  u=f[:]->U(:,{110.6387},:,:)
  v=f[:]->V(:,{110.6387},:,:)
  z=f[:]->Z3(:,{110.6387},:,:)
  printVarSummary(u)
  printVarSummary(v)
  printVarSummary(z)
  utim  = dim_avg_n(u,0)
  vtim  = dim_avg_n(v,0)
  ztim  = dim_avg_n(z,0) /10

  wks  = gsn_open_wks("png","uv_wsgd")
  res  = True         
  res@gsnLeftString  = ""
  res@gsnRightString  = ""

  res@pmTickMarkDisplayMode = "Always"
  res@mpFillOn     = False
  res@mpMinLatF = -10         
  res@mpMaxLatF = 70
  res@mpMinLonF = 20
  res@mpMaxLonF = 200
  res@mpOutlineOn  = True

  res@vcGlyphStyle = "LineArrow"  
  res@vcMinMagnitudeF =1.0
  res@vcMinDistanceF =0.03
  res@vcLineArrowThicknessF = 2.5
  res@vcLineArrowHeadMaxSizeF =0.01

  res@vcRefAnnoOn = True  
  res@vcRefMagnitudeF = 20      
  res@vcRefAnnoString1On = True        
  res@vcRefAnnoString2On = False         
  res@vcRefAnnoString1 = "20m/s"
  res@vcRefAnnoSide = "Top"
  res@vcRefLengthF = 0.03
  res@vcRefAnnoOrthogonalPosF = -0.12
  res@vcRefAnnoParallelPosF = 0.999

  sres  = True         
  sres@cnLevelSelectionMode = "ManualLevels"  
  sres@cnLevelSpacingF = 10            

  plot = gsn_csm_vector_map(wks, utim, vtim, res)
  plot_ov = gsn_csm_contour(wks,ztim,sres)

  overlay(plot,plot_ov)                     
  draw(plot)                              
  frame(wks)                             
end

packard

ncl 画图是这样：画图函数不止看数据，还看数据的coordinate和attributes。有些操作会使得数据的coordinates和attribute弄丢。那三行可以改成这四行。
  utim  = dim_avg_n_Wrap(u,0)
  vtim  = dim_avg_n_Wrap(v,0)
  ztim  = dim_avg_n_Wrap(z,0)
  ztim  = ztim /10
加上 _Wrap的函数会保留coordinate 和 attributes
分开两步，在第一步给好coord和att以后，在第二步再除以10，这样才能保留ztim的coord 和 att
可以在画图语句前 printVarSummary(ztim)确认一下数据有没有经纬度信息。
其他建议：mpMinLatF 等等目前没起作用。如果你不想画出全部数据，需要 res@mpLimitMode ="LatLon"，这样 mpMinLatF才起作用。

肉粽子

packard 发表于 2018-1-13 09:10
ncl 画图是这样：画图函数不止看数据，还看数据的coordinate和attributes。有些操作会使得数据的coordinate ...

您说的没错！我刚试了一下，已经解决问题了！谢谢您，这是我第一次发帖子求助，就有这么详细的解释，非常开心！！！超级感谢您哦！！！

packard

肉粽子 发表于 2018-1-13 10:23
您说的没错！我刚试了一下，已经解决问题了！谢谢您，这是我第一次发帖子求助，就有这么详细的解释，非常 ...

不用那么客气。我也是论坛的新人啦。大家互相交流，共同进步嘛！