ncl使用ncep fnl 资料画500hPa高度场和850hPa风场

Anonymous888

使用ncep fnl 资料画500hPa高度场和850hPa风场

• begin
• filename = "fnl_20180516_00_00"
• f = addfile(filename + ".grib2", "r")
• hgt = f->HGT_P0_L100_GLL0({50000}, :, :)
• hgt = hgt * 0.1
• u = f->UGRD_P0_L100_GLL0({85000}, ::4, ::4)
• u = u * 2.5
• v = f->VGRD_P0_L100_GLL0({85000}, ::4, ::4)
• v =v * 2.5
• wks = gsn_open_wks("pdf", "./test/" + filename)
• res = True
• res@gsnDraw = False
• res@gsnFrame = False
• res@gsnLeftString = ""
• res@gsnRightString = ""
• ;>---------------------------------------<
• ;            set for the map
• ;>---------------------------------------<
• mpres = res
• mpres@mpFillOn                = False
• mpres@mpMinLatF               = 10.
• mpres@mpMaxLatF               = 80.
• mpres@mpMinLonF               = 60.
• mpres@mpMaxLonF               = 140.
• mpres@mpDataBaseVersion       = "MediumRes"
• mpres@mpDataSetName           = "Earth..4"
• mpres@mpOutlineSpecifiers     = (/"China:states"/)
• mpres@pmTickMarkDisplayMode  = "Always"
• mpres@tmXBMajorLengthF = 0.005
• ;>---------------------------------------<
• ;>---------------------------------------<
• ;       set resource for contour plot
• ;>---------------------------------------<
• cnres = res
• cnres@cnSmoothingOn = True ;
• cnres@cnSmoothingDistanceF   = 0.001
• cnres@cnLevelSelectionMode   = "ManualLevels"
• cnres@cnMinLevelValF = 500
• cnres@cnMaxLevelValF = 600
• cnres@cnLevelSpacingF = 4
• cnres@cnInfoLabelOn = False
• cnres@cnLineLabelsOn          =  True
• cnres@cnLineLabelFontHeightF = 0.01
• cnres@cnLineThicknessF = 2.0
• cnres@cnLineLabelInterval = 1
• ;>---------------------------------------<
• ;>---------------------------------------<
• ;     set resource for windBarb plot
• ;>---------------------------------------<
• vcres                           = res
• vcres@gsnAddCyclic = False
• vcres@vcGlyphStyle               = "WindBarb"
• vcres@vcRefLengthF               = 0.02
• vcres@vcRefAnnoOn               = False
• vcres@vcWindBarbLineThicknessF  = 1.5
• vcres@vcWindBarbColor = "black"
• vcres@vcMinMagnitudeF = 0.01
• vcres@vcWindBarbTickLengthF = 0.35
• ;>---------------------------------------<
• mapplot = gsn_csm_map(wks, mpres)
• cnplot = gsn_csm_contour(wks, hgt, cnres)
• vcplot = gsn_csm_vector(wks, u, v, vcres)
• overlay(mapplot, cnplot)
• overlay(mapplot, vcplot)
• draw(mapplot)
• frame(wks)
• end
  

yysunnyboy

请问：hgt * 0.1 这里为什么要乘0.1呢？  u = u * 2.5 这里为什么需要乘2.5呢？谢谢！

daoggy

楼主，脚本中vcRefMagnitudeF = 15是什么意思？
我设置了vcRefMagnitudeF = 4，
以及vcWindBarbScaleFactorF = 2.5，
是可以显示参考风向杆为4m/s的，这样对吗？

yysunnyboy

谢谢楼主大人可否贴一下数据连接呢？ 谢谢！

Anonymous888

yysunnyboy 发表于 2018-6-29 02:39
谢谢楼主大人可否贴一下数据连接呢？ 谢谢！

http://bbs.06climate.com/forum.p ... &extra=page%3D1

Anonymous888

yysunnyboy 发表于 2018-6-29 03:01
请问：hgt * 0.1 这里为什么要乘0.1呢？  u = u * 2.5 这里为什么需要乘2.5呢？谢谢！

hgt * 0.1 位势米转为位势什米；u * 2.5 ncl中10knots为一个短杆，国内4m/s为一个短杆，所以需要放大2.5倍

zhaolanxiai

风场应该有问题吧，不是东北风就是西南风，看上去感觉怪怪的。

Anonymous888

zhaolanxiai 发表于 2018-6-29 08:33
风场应该有问题吧，不是东北风就是西南风，看上去感觉怪怪的。

谢谢指出，确实是这样，不知道问题出在哪

Anonymous888

zhaolanxiai 发表于 2018-6-29 08:33
风场应该有问题吧，不是东北风就是西南风，看上去感觉怪怪的。

谢谢指出，确实是这样，不知道问题出在哪

Anonymous888

zhaolanxiai 发表于 2018-6-29 08:33
风场应该有问题吧，不是东北风就是西南风，看上去感觉怪怪的。

谢谢指出，确实是这样，不知道问题出在哪？

yysunnyboy

Anonymous888 发表于 2018-6-29 08:32
hgt * 0.1 位势米转为位势什米；u * 2.5 ncl中10knots为一个短杆，国内4m/s为一个短杆，所以需要放大2.5 ...

谢谢楼主回复。ncl中10knots为一个短杆，请问这个“短杆”是什么意思啊？ NCL中有相关说明吗？另外，10 knot =5.14 米 / 秒，楼主为什么要乘以2.5呢？我是小白，还请楼主指导啊！

我还发现一个错误，第9行代码 v =u * 2.5， 应该是 v =v * 2.5吧？！