ncl为什么画图出来像扫描一样？

一大碗年糕

begin
data = fbindirread("/home/ramsey/Documents/r/rr11.grd", 0, (/61,71/), "float")

;------设定经度坐标---------
lon = ispan(70, 140, 1)
lon!0 = "lon"
lon@long_name = "longtitude"
lon@units = "degrees_east"
;-------设定纬度坐标--------
lat = ispan(0, 60, 1)
lat!0 = "lat"
lat@long_name = "latitude"
lat@units = "degrees_north"
;-----设置变量元数据-------
data!0 = "lat"
data!1 = "lon"
data&lat = lat
data&lon = lon
data@long_name = "Correlation Coefficient"

;------plot------
wks = gsn_open_wks("png", "rr1")

res = True
res@gsnAddCyclic = False
res@mpMinLatF = 0
res@mpMaxLatF = 60
res@mpMinLonF = 70
res@mpMaxLonF = 140

;res@cnLevelSelectionMode = "ManualLevels"
;res@cnMinLevelValF = -1
;res@cnMaxLevelValF = 1
;res@cnLevelSpacingF = 0.1

res@cnLinesOn = False
res@cnFillOn = True
res@cnFillMode = "RasterFill"
res@cnRasterSmoothingOn = True

res@tiMainString = "~F9~ Correlation Coefficient to Nanjing"
res@tiMainOffsetYF = -0.035
res@gsnLeftString = ""

res@pmTickMarkDisplayMode = "Always"
res@lbBoxLinesOn = False
plot = gsn_csm_contour_map(wks, data, res)
end
经常出现这样的问题，数据应该是没问题的，我感觉是fbindirread这个函数的读取问题？数据就是71*61的二维数组

轩-瑾

有可能是数组大小反了

一大碗年糕

轩-瑾 发表于 2020-3-19 13:45
有可能是数组大小反了

谢谢，确实是这个问题我把这个和fbinrecread函数搞混了，以为fbindirread也是要按右边维变化

一大碗年糕

问题解决，但是不知道为什么按（71*61）读入，NCL还是报错，可能涉及到NCL右边维变化快的原理？所以用了transpose转置后变为（61*71）成功画图。