NCL出图有一张多余空白页

hhumuer

用NCL画FNL环流形势，并用overlay将风场叠加，但是Fram(wks)没起作用，还是什么其它原因，导致出图时，前面总是多出一张空白图，不知道是什么原因呢，还请各位在神指导！脚本如下：

load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
begin
  fi  = addfile("./fnl_20140928_00_00.grib2","r")
  hgt=fi->HGT_P0_L100_GLL0(13,:,:)
  u  =fi->UGRD_P0_L100_GLL0 (13,:,:)
  v  =fi->VGRD_P0_L100_GLL0 (13,:,:)
  printMinMax (hgt, True)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  wks_type="pdf"
  wks_name="500hpa"
  wks = gsn_open_wks(wks_type,wks_name)
  gsn_define_colormap(wks,"gui_default")
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  res = True
  res@gsnDraw = False
  res@gsnFrame= False
  
  res@mpMinLatF = 3
  res@mpMaxLatF = 80
  res@mpMinLonF = 43
  res@mpMaxLonF = 165
  res@mpFillOn               = False   
  res@mpGeophysicalLineColor = "Black"
  res@mpNationalLineColor    = "Black"
  res@mpUSStateLineColor     = "Black"
  res@mpGridLineColor        = "Black"
  res@mpLimbLineColor        = "Black"
  res@mpPerimLineColor       = "Black"
  res@mpOutlineBoundarySets  ="National"
  res@mpDataBaseVersion="MediumRes"   
  res@mpDataSetName="Earth..4"         
  res@mpOutlineSpecifiers = "China:states"  
  res@cnFillOn = False   
  res@cnLinesOn = True
  res@cnLineLabelsOn = True  
  res@cnInfoLabelOn = False ; set false will not set an information label
  res@cnLevelSelectionMode = "ManualLevels"
  res@cnMinLevelValF = 4700
  res@cnMaxLevelValF = 6000
  res@cnLevelSpacingF = 20
  res@gsnSpreadColors = True ; 6.1.0
  res@lbBoxLinesOn = False ; Label bar
  res@lbLabelAutoStride     = True            
  base = gsn_csm_contour_map(wks, hgt, res)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
resvc=True
  resvc@gsnDraw = False

  resvc@vcRefMagnitudeF = 30.0
  resvc@vcRefLengthF    = 0.045
  resvc@vcMinDistanceF  = 0.019
  resvc@vcGlyphStyle    ="CurlyVector"
  resvc@gsnLeftString   =""
  resvc@gsnRightString  =""
  plot=gsn_csm_vector(wks,u,v,resvc)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   overlay(base,plot)  
   draw(base)
   frame(wks)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
end   

longlivehj

resvc@gsnFrame= False

deeli

frame(wks)删掉试试~

hhumuer

longlivehj 发表于 2015-10-27 08:02
resvc@gsnFrame= False

楼上正解，厉害，赞！{:eb508:}{:eb508:}

hhumuer

deeli 发表于 2015-10-27 08:05
frame(wks)删掉试试~

试过了，如楼上所说，设置resvc@gsnFrame= False可以解决空白页，谢谢哈